From 4682deeb62247d34de87f8e777f99e2d337fd377 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?J=C3=B6rg=20Frings-F=C3=BCrst?= <debian@jff.email>
Date: Sun, 20 Oct 2024 15:21:43 +0200
Subject: New upstream version 1.3

---
 gnulib-m4/pthread_mutex_timedlock.m4 | 48 ++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 gnulib-m4/pthread_mutex_timedlock.m4

(limited to 'gnulib-m4/pthread_mutex_timedlock.m4')

diff --git a/gnulib-m4/pthread_mutex_timedlock.m4 b/gnulib-m4/pthread_mutex_timedlock.m4
new file mode 100644
index 00000000..9b175d54
--- /dev/null
+++ b/gnulib-m4/pthread_mutex_timedlock.m4
@@ -0,0 +1,48 @@
+# pthread_mutex_timedlock.m4
+# serial 6
+dnl Copyright (C) 2019-2024 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([gl_FUNC_PTHREAD_MUTEX_TIMEDLOCK],
+[
+  AC_REQUIRE([gl_PTHREAD_H_DEFAULTS])
+
+  AC_CHECK_DECL([pthread_mutex_timedlock],
+    [dnl Test whether the gnulib module 'threadlib' is in use.
+     dnl Some packages like Emacs use --avoid=threadlib.
+     dnl Write the symbol in such a way that it does not cause 'aclocal' to pick
+     dnl the threadlib.m4 file that is installed in $PREFIX/share/aclocal/.
+     m4_ifdef([gl_][THREADLIB], [
+       AC_REQUIRE([gl_][THREADLIB])
+       dnl Test whether the function actually exists.
+       dnl FreeBSD 5.2.1 declares it but does not define it.
+       AC_CACHE_CHECK([for pthread_mutex_timedlock],
+         [gl_cv_func_pthread_mutex_timedlock_in_LIBMULTITHREAD],
+         [gl_saved_LIBS="$LIBS"
+          LIBS="$LIBS $LIBMULTITHREAD"
+          AC_LINK_IFELSE(
+            [AC_LANG_PROGRAM(
+               [[#include <pthread.h>
+                 #include <time.h>
+               ]],
+               [[pthread_mutex_t lock;
+                 struct timespec ts = { 0 };
+                 return pthread_mutex_timedlock (&lock, &ts);
+               ]])
+            ],
+            [gl_cv_func_pthread_mutex_timedlock_in_LIBMULTITHREAD=yes],
+            [gl_cv_func_pthread_mutex_timedlock_in_LIBMULTITHREAD=no])
+          LIBS="$gl_saved_LIBS"
+         ])
+       if test $gl_cv_func_pthread_mutex_timedlock_in_LIBMULTITHREAD != yes; then
+         HAVE_PTHREAD_MUTEX_TIMEDLOCK=0
+       fi
+     ], [
+       :
+     ])
+    ],
+    [HAVE_PTHREAD_MUTEX_TIMEDLOCK=0],
+    [[#include <pthread.h>]])
+])
-- 
cgit v1.2.3